// supercollider
(
play {
	var sig, click, osc, env, saw;
	env = Env([0, 1, 1, 0], [60, 60*8, 60], \sin).kr;
	click = LFPulse.ar([1, 2, 5]/6).sum * 0.05;
	osc = SinOsc.ar(
		[80, 80.01],
		mul: 0.05,
		phase: SinOsc.ar(40, mul: click * AllpassC.kr(env, 60, 60).linexp(0, 1, 0.01, 1) * LFNoise1.kr(1/30).range(8pi, 24pi))
	);
	saw = Saw.ar(80*[3.5, 4], mul: 0.02) * SinOsc.kr(0.12/100, phase: [pi/4+pi, pi]).clip(0, 1);
	saw = Splay.ar(saw, 0.75);
	sig = LPF.ar(osc + click + saw, 80 * 10) * env;
	sig = LeakDC.ar(sig);
	JPverb.ar(sig, 0.1, size: 4) + sig;
};
s.record;
fork {
	(60 * 10).wait;
	s.stopRecording
}
);

synthruary 2022 01 - Minimalism

Synthruary 2 - arpeggiators

// supercollider code

// create arp buffers
(
~buffer = Buffer.loadCollection(s, [ 1.0, 4.0, 1.0, 6.0, 4.0, 5.0, 3.0, 3.0, 0.0, 2.0 ]);
~amps   = Buffer.loadCollection(s, [ 0.75, 0.25, 1.0, 0.75, 0.75, 0.25, 0.75, 0.75, 0.75, 0.75 ]);
)

// define synthdef
(
SynthDef(\arp, {|root=400, min=30, max=30, gate=1|
	var clock, index, note, freq, amp, sig;
	clock = LFPulse.ar(LFSaw.kr(1/3).range(min, max));
	index = PulseCount.ar(clock).mod([6, ~buffer.numFrames, 4]);
	note = BufRd.ar(1, ~buffer, index, interpolation: 1);
	freq = root * SelectX.ar(note, Scale.major.ratios.collect(DC.ar(_))).lag(0.01);
	amp = BufRd.ar(1, ~amps, index, interpolation: 1);
	sig = gate * Splay.ar(amp.lag * SinOsc.ar(freq * [1,3,2], mul: 0.2, phase: SinOsc.ar(freq*2*LFNoise1.kr(1/4).range(0.98, 1.02), mul: pi/4 * amp.lag)));
	Out.ar(0, AllpassN.ar(sig, 1/4, 1/4, 10) * 0.6 + sig);
}).store;
)

// evaluate to start high pitched fast arp
~high = Synth(\arp, [\root, 400])

// after 16 measures of the above,
// evaluate to start lower, slower arp
~low = Synth(\arp, [\root, 200, \min, 0, \max, 2])

// after 4 cycles of the above, activate the LFO
~high.set(\min, 20); ~high.set(\max, 30);

// when the moment feels right, end the piece
~high.set(\gate, 0); ~low.set(\gate, 0);

synthruary 2022 02 - Arpeggiators

Hi! I'm a music robot. I say bloop and bleep and write a lot of songs very fast. Hear me change over time!

contact
nil@synthony.app

Synthruary 2 - arpeggiators

nil-arity

Recent comments

Alisia Mentzer

Related tracks